Supplementary Information: NONMEM Control Stream
$PROBLEM NO2 MODEL
$DATA NO_data.CSV IGNORE=#
$INPUT ID,TIME,AMT,RATE,DUR,DV,CMT,MDV,EVID,DIST,PKPD,SEXF,RACE,AGE,BWKG,MABP,NO2P,NO3P,NO2R,NO3R,HB3,NO2W,NO3W,DMG,DMGKG,HBUM
;------
$SUBROUTINES ADVAN8 TOL=4
;------
$MODEL
COMP=NO2P
COMP=NO2R
COMP=NO3P
COMP=NO3R
COMP=Hb3
COMP=NO2T
COMP=NO3T
COMP=KMR
COM=NOR
;------
$PK
IF(DUR.GT.0) D1=DUR
R1=AMT/D1
IF (DUR.GT.0) AMTD=AMT
DMG2=AMTD*69/1000
IF (DUR.GT.0) DURD=DUR
RMGH=DMG2/DURD*60
TVQ=THETA(1)
Q=TVQ*EXP(ETA(1))
TVV4=THETA(2)
V4=TVV4*EXP(ETA(2))
TVKPTNO3=THETA(3)
KPTNO3=TVKPTNO3
TVKTPNO3=THETA(4)
KTPNO3=TVKTPNO3
TVKPRNO2=THETA(5)
KPRNO2=TVKPRNO2*EXP(ETA(3))
TVKRPNO3=THETA(6)
KRPNO3=TVKRPNO3*EXP(ETA(4))
TVKNO3P=THETA(7)
KNO3P=TVKNO3P*EXP(ETA(5))
TVKNO3R=THETA(8)
DKNO3R=TVKNO3R*EXP(ETA(6))
KNO3R=DKNO3R/1000
TVKNOR=THETA(9)
DKNOR=TVKNOR
KNOR=DKNOR/1000
TVVRBC_NO3=THETA(10)
VRBC_NO3=TVVRBC_NO3*EXP(ETA(8))
TVVRBC_NO2=THETA(11)
VRBC_NO2=TVVRBC_NO2*EXP(ETA(13))
TVCLR2=THETA(12)
S_NO2=THETA(16)*EXP(ETA(14))
CLR2=TVCLR2*EXP(ETA(9))
TVV1=THETA(13)
V1=TVV1*EXP(ETA(10))
TVV5=THETA(14)
V5=TVV5*EXP(ETA(11))
TVV3=THETA(15)
V3=TVV3*EXP(ETA(12))
TVKMYO=THETA(24)
DKMYO=TVKMYO
TVKTRDT=THETA(25)
DKTRDT=TVKTRDT
KTRDT=DKTRDT/1000
TVKNO2RDT=THETA(26)
DKNO2RDT=TVKNO2RDT*EXP(ETA(15))
KNO2RDT=DKNO2RDT/1000
S_NO3=THETA(17)*EXP(ETA(7))
TVCLR3=THETA(27)
CLR3=TVCLR3*EXP(ETA(16))
TVKDEG=THETA(28)
KDEG=TVKDEG
TVSTIM=THETA(29)
STIM=TVSTIM*EXP(ETA(17))
TVKHBNO=THETA(32)
DKHBNO=TVKHBNO*EXP(ETA(18))
KHBNO=DKHBNO/1000
TVFRHBNO=THETA(33)
FRHBNO=TVFRHBNO*EXP(ETA(19))
S1=V1
S2=VRBC_NO2
S3=V3
S4=VRBC_NO3
S5=V5
IF (TIME.EQ.0) AHB30=HB3
HB30=AHB30*V5
IF (TIME.EQ.0) HBUMD=HBUM
HBT=HBUMD*V5
HB0=(HBT-HB30)*0.23
HBO20=(HBT-HB30)*0.77
IF (TIME.EQ.0) CNO2P0=NO2P
NO2P0=CNO2P0*V1
A_0(1)=NO2P0
NO2R0=KPRNO2*NO2P0/(KNOR*HB0 + KNO3R*HBO20)
A_0(2)=NO2R0
DIET=0
DIET1=10*V3
DIET5=39*V3
DIET6=42*V3
IF (ID.EQ.1) DIET=DIET1
IF (ID.EQ.5) DIET=DIET5
IF (ID.EQ.6) DIET=DIET6
KELNO2=CLR2/V1
KELNO3=CLR3/V3
KMYO= KNO3R*HBO20
KPTNO2=Q/V1
KTPNO2=Q/V4
NOR0=KNOR*HB0*NO2R0/(KHBNO*(HB0*(1-FRHBNO)+FRHBNO*HBO20))
NO3R0=KNO3R*NO2R0*HBO20/KRPNO3+KHBNO*FRHBNO*NOR0*HBO20/KRPNO3
B=KELNO3+KNO2RDT+KPTNO3
D=KTPNO2+KMYO
E=(KPTNO2/KTPNO3 - KTPNO2*KPTNO2/(KTPNO3*D) + KPTNO3*KNO3P/(KTPNO3*B))*NO2P0
H=KPTNO3*KRPNO3/(KTPNO3*B)*NO3R0
NO3T0=(E + H) * (B*D*KTPNO3/(B*D*KTPNO3-(D*KTPNO3*KPTNO3-B*KTRDT*KTPNO2)))
NO2T0=(KPTNO2*NO2P0+KTRDT*NO3T0)/(KTPNO2+KMYO)
NO3P0=(KNO3P*NO2P0 + KRPNO3*NO3R0 + KTPNO3*NO3T0)/(KNO2RDT + KPTNO3 + KELNO3)
A_0(3)=NO3P0 + DIET
A_0(4)=NO3R0
A_0(5)=HB30
A_0(6)=NO2T0
A_0(7)=NO3T0
KMR0=(KNOR*NO2R0*HB0 + KNO3R*NO2R0*HBO20+KHBNO*FRHBNO*NOR0*HBO20)/HB30
A_0(8)=KMR0
A_0(9)=NOR0
KINNO2=KELNO2*NO2P0 + KELNO3*NO3P0 + KHBNO*Hb0*NOR0*(1-FRHBNO)
KSYN= KDEG*KMR0
;------
$DES
HB=(HBT-A(5))*0.23
HBO2=(HBT-A(5))*0.77
CHB=HB/V5
CHBO2=HBO2/V5
CHBT=HBT/V5
DHB3 = A(5) - HB30
H_HB3=STIM*(DHB3/V5)
DNO2P = A(1) - NO2P0
H_NO2=S_NO2*(DNO2P/V1)
DNO3P = A(3) - NO3P0
H_NO3=S_NO3*(DNO3P/V3)
DADT(1)=KINNO2 + KNO2RDT*A(3) + KTPNO2*A(6) - KPTNO2*A(1) - KNO3P*A(1) - KPRNO2*A(1) - CLR2*(1+H_NO2)/V1*A(1)
DADT(2)=KPRNO2*A(1) - KNOR*A(2)*HB - KNO3R*A(2)*HBO2
DADT(3)=KNO3P*A(1) + KRPNO3*A(4) - KNO2RDT*A(3) - CLR3*(1+H_NO3)/V3*A(3) - KPTNO3*A(3) + KTPNO3*A(7)
DADT(4)=KNO3R*A(2)*HBO2- KRPNO3*A(4)+ KHBNO*FRHBNO*A(9)*HBO2
DADT(5)=KNOR*A(2)*HB + KNO3R*A(2)*HBO2 - A(8)*A(5)+KHBNO*FRHBNO*A(9)*HBO2
DADT(6)=KPTNO2*A(1) - KTPNO2*A(6) + KTRDT* A(7) - KMYO* A(6)
DADT(7)=KPTNO3*A(3) - KTPNO3*A(7) - KTRDT* A(7) + KMYO* A(6)
DADT(8)=KSYN *(1+H_HB3) - KDEG*A(8)
DADT(9)=KNOR*A(2)*HB-KHBNO*FRHBNO*A(9)*HBO2-KHBNO*(1-FRHBNO)*A(9)*HB
;------
$ERROR
CNO2P=A(1)/V1
CNO2R=A(2)/VRBC_NO2
CNO3P=A(3)/V3
CNO3R=A(4)/VRBC_NO3
CHB3=A(5)/V5
IPRED=F
W=1
IF (CMT.EQ.1) THEN
IPRED=CNO2P
W=SQRT(THETA(18)**2+(THETA(19)*IPRED)**2)
Y1=IPRED+W*EPS(1)
Y=Y1
ENDIF
IF (CMT.EQ.2) THEN
IPRED=CNO2R
W=SQRT(THETA(30)**2+(THETA(31)*IPRED)**2)
Y2=IPRED+W*EPS(1)
Y=Y2
ENDIF
IF (CMT.EQ.3) THEN
IPRED=CNO3P
W=SQRT(THETA(20)**2+(THETA(21)*IPRED)**2)
Y3=IPRED+W*EPS(2)
Y=Y3
ENDIF
IF (CMT.EQ.4) THEN
IPRED=CNO3R
W=SQRT(THETA(20)**2+(THETA(21)*IPRED)**2)
Y4=IPRED+W*EPS(2)
Y=Y4
ENDIF
IF (CMT.EQ.5) THEN
IPRED=CHB3
W=SQRT(THETA(22)**2+(THETA(23)*IPRED)**2)
Y5=IPRED+W*EPS(3)
Y=Y5
ENDIF
IRES = IPRED - DV
IWRES=IRES/W
;------
$THETA
(2,22.5225,30) ; 1 TVQ
(1,17.089,70) ; 2 TVV4
(0.003,0.033,0.3) ; 3 TVKPTNO3
(0.01,0.108,1) ; 4 TVKTPNO3
(0.01,0.0224736,0.2) ; 5 TVKPRNO2
(0.002,0.00463624,0.04) ; 6 TVKRPNO3
(0 FIX) ; 7 TVKNO3P
(0.001,0.00725,0.03) ; 8 TVKNO3R
(0.07,0.232,2) ; 9 TVKNOR
(1.0,3.51,6) ; 10 VRBC_NO3
(0.5,4.11,8.0) ; 11 VRBC_NO2
(0.15,0.72581,3) ; 12 TVCLR0NO2
(215,318.202,500) ; 13 TVVP
(0.4,1.9911,10) ; 14 TVVRBC_Hb3
(5,15.684,30) ; 15 TVVNO3P ; L
(0.05,2.736911,6) ; 16 S_NO2
(0.001,0.0182365,0.1) ; 17 S_NO3
(0.0001,0.00349904,0.02) ; 18 NO2 ADDITIVE
(0.03,0.326689,3) ; 19 NO2 PROPORTIONAL
(0.02,0.114461,1) ; 20 NO3 ADDITIVE
(0.02,0.235148,1) ; 21 NO3 PROPORTIONAL
(2,14.9548,30) ; 22 HB3 ADDITIVE
(0.01,0.134956,1) ; 23 HB3 PROPORTIONAL
(0 FIX) ; 24
(0, 0.0984302,1) ; 25 TVKTRDT
(0.01,0.4506491,4) ; 26 TVKNO2RDT
(0.009,0.012079,0.5) ; 27 CLR3_0
(0.009,0.0269537,0.2) ; 28 KDEG
(0.009,0.0245252,0.2) ; 29 STIM
(0.009,0.0102723,0.02) ; 30 NO2R ADDITIVE
(0.05,0.590917,3) ; 31 NO2R PROPORTIONAL
(0.0002,0.0205397,0.09) ; 32 TVKHBNO
(0.001,0.020098,1.0) ; 33 TVFRHBNO
;------
$OMEGA
2.93E-01 ;1 TVQ
3.23E-01 ;2 TVV4
3.24E-01 ;3 KPRNO2
4.09E-01 ;4 KRPNO3
0 FIX ;5 KNO3P
9.56E-02 ;6 KNO3R
0 FIX ;7 S_NO3
0 FIX ;8 VRBC_NO3
0 FIX ;9 CLR2
1.83E-01 ;10 VP
8.06E-02 ;11 VRBC
0 FIX ;12 V3
4.85E-02 ;13 VRBC_NO2
0 FIX ;14 S_NO2
4.68E-01 ;15 KNO2RDT
3.04E-01 ;16 CLR3
3.03E-02 ;17 STIM
0 FIX ;18 KHBNO
0 FIX ;19 FRHBNO
;------
$SIGMA
1 FIX
1 FIX
1 FIX
;------
$ESTIMATION MAXEVAL=9999 PRINT=15 SIG=3 METHOD=1 INTERACTION NOABORT REPEAT
$TABLE ID TIME DV MDV CMT IPRED IWRES
Supplementary Information: NONMEM Data file
Datafile was truncated to show as an example.
#ID / TIME / AMT / RATE / DUR / DV / CMT / MDV / EVID / DIST / PKPD / SEXF / RACE / AGE / BWKG / MABP / NO2P / NO3P / NO2R / NO3R / HB3 / NO2W / NO3W / DMG / DMGKG / HBUM1 / 0 / 12811.2 / -2 / 2880 / . / 1 / 1 / 1 / . / . / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 0 / . / . / . / . / 1 / 0 / 0 / 0 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 0 / . / . / . / . / 2 / 0 / 0 / 1 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 0 / . / . / . / . / 3 / 0 / 0 / 3 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 0 / . / . / . / . / 4 / 0 / 0 / 4 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 0 / . / . / . / . / 5 / 0 / 0 / . / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 2 / . / . / . / . / 1 / 0 / 0 / 0 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 2 / . / . / . / . / 2 / 0 / 0 / 1 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 2 / . / . / . / . / 3 / 0 / 0 / 3 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 2 / . / . / . / . / 4 / 0 / 0 / 4 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 2 / . / . / . / . / 5 / 0 / 0 / . / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 5 / . / . / . / . / 1 / 0 / 0 / 0 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 5 / . / . / . / . / 2 / 0 / 0 / 1 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 5 / . / . / . / . / 3 / 0 / 0 / 3 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 5 / . / . / . / . / 4 / 0 / 0 / 4 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 5 / . / . / . / . / 5 / 0 / 0 / . / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 10 / . / . / . / . / 1 / 0 / 0 / 0 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 10 / . / . / . / . / 2 / 0 / 0 / 1 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 10 / . / . / . / . / 3 / 0 / 0 / 3 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 10 / . / . / . / . / 4 / 0 / 0 / 4 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 10 / . / . / . / . / 5 / 0 / 0 / . / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 20 / . / . / . / . / 1 / 0 / 0 / 0 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 20 / . / . / . / . / 2 / 0 / 0 / 1 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 20 / . / . / . / . / 3 / 0 / 0 / 3 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 20 / . / . / . / . / 4 / 0 / 0 / 4 / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6
1 / 20 / . / . / . / . / 5 / 0 / 0 / . / 0 / . / . / . / . / 97 / 0.1 / 13.4 / 0.2 / 8.3 / 76 / 0.1 / 12.4 / 883.9 / 12.8 / 7037.6