NONMEM code
The simulated data set number 4, in scenario 6 of set-up C (in which the correlation between covariates was 0.2 and the correlation between CL and V was 0.3), was generated using the following command in sse tool in PsN version 4.5.10.
sse true_model.mod -samples=100
true_model.mod is the true model to generate the data set (mc-sim-4.dat). In order to run adjusted adaptive Lasso ( AALasso) on the simulated data set, the following command should be run in PsN.
Lasso run102.mod –relations=CL:cov1-2, cov2-2, cov3-2, cov4-2, cov5-2, cov6-2, cov7-2, cov8-2, cov9-2, cov10-2 -retries=5 –picky –stop_t=4 -log_scale -adjusted -seed=8098
Run102. mod is the basic model which includes no covariates. The NONMEM codes for the true model, basic model and final model for AALasso are as:
############### True model (true_model.mod) for Scenario 6 of Set-up C ###################
;;1. Description:true model for Set-up C, the correlation between covariates is 0.2, the correlation between CL ;; and V is 0.3
;;2. Structural model: one compartment i.v bolus model
;;3. Inter-individual variability: omega is 15%
;;4 Inter-occasion variability: no
;;5. Residual variability: sigma is 10%
$PROBLEM ADDITIVEERROR MODEL #1
$INPUT ID TIME AMT EVID DV COV1 COV2 COV3 COV4 COV5 COV6 COV7 COV8 COV9 COV10
$DATA AL1.csv IGNORE=@
$PRED
IF(ICALL.EQ.4) THEN ;this is code for doing simulations
COV1=ETA(3)
COV2=ETA(4)
COV3=ETA(5)
COV4=ETA(6)
COV5=ETA(7)
COV6=ETA(8)
COV7=ETA(9)
COV8=ETA(10)
COV9=ETA(11)
COV10=ETA(12)
ENDIF
LNTVCL = THETA(1)+THETA(3)*COV1+THETA(4)*COV2+THETA(5)*COV3+THETA(6)*COV4 ; typical value of CL with effects of 4 covariates
LNTVV = THETA(2)
CL = EXP(LNTVCL+ETA(1)) ; individual value of CL
V = EXP(LNTVV+ETA(2))
DOSE=1
IPRED=LOG(DOSE/V*EXP(-TIME*CL/V))
Y=IPRED+EPS(1)
$THETA (-0.3667) ; 1. LNTVCL ; (lower bound,initial estimate)
$THETA (0.01) ; 2.LNTVV; (lower bound,initial estimate)
$THETA (0.25) ; cov1
$THETA (0.15) ; cov2
$THETA (0.1) ; cov3
$THETA (0.05) ; cov4
$OMEGA BLOCK(2) 0.0225 ; var ETA(1) ; initial estimate
0.00675 0.0225 ; initial estimate cavariance ETA(1) & ETA(2), var ETA(2)
$OMEGA BLOCK(10) 1 FIX ; var(COV1) will not be changed
0.2 1
0.2 0.2 1
0.2 0.2 0.2 1
0.2 0.2 0.2 0.2 1
0.2 0.2 0.2 0.2 0.2 1
0.2 0.2 0.2 0.2 0.2 0.2 1
0.2 0.2 0.2 0.2 0.2 0.2 0.2 1
0.2 0.2 0.2 0.2 0.2 0.2 0.2 0.2 1
0.2 0.2 0.2 0.2 0.2 0.2 0.2 0.2 0.2 1
$OMEGA 1 FIX ; var(COV2) will not be changed during estimation
$OMEGA 1 FIX ; var(COV3) will not be changed during estimation
$OMEGA 1 FIX ; var(COV4) will not be changed during estimation
$OMEGA 1 FIX ; var(COV5) will not be changed during estimation
$OMEGA 1 FIX ; var(COV6) will not be changed during estimation
$OMEGA 1 FIX ; var(COV7) will not be changed during estimation
$OMEGA 1 FIX ; var(COV8) will not be changed during estimation
$OMEGA 1 FIX ; var(COV9) will not be changed during estimation
$OMEGA 1 FIX ; var(COV10) will not be changed during estimation
$SIGMA 0.01 ; var prop err ; initial estimate
$SIMULATION (12345 NEW) NSUB=1
$ESTIMATION METHOD=1 INTER MAXEVAL=9999
;$COVARIANCE
$TABLE ID TIME IPRED CWRES CWRESI NOPRINT ONEHEADER
FILE=sdtab1
$TABLE ID ETA(1) ETA(2) COV1 COV2 NOPRINT NOAPPEND ONEHEADER
FILE=patab1
Basicmodel(run102.mod) for Scenario 6 of Set-up C######################################
;;1. Description: Basic model for AALasso, Set up 3,correlation 0.3 among CL & V in the data set
;;2. Structural model: one compartment i.v bolus model
;;3. Inter-individual variability: omega is 15%
;;4. Inter-occasion variability: no
;;5. Residual variability: sigma is 10%
$PROBLEM ADDITIVEERROR MODEL
$INPUT ID TIME AMT EVID DV COV1 COV2 COV3 COV4 COV5 COV6 COV7 COV8 COV9 COV10
$DATA ../../../sserun/m1/mc-sim-4.dat IGNORE=@
$PRED
LNTVCL = THETA(1)
LNTVV = THETA(2)
CL = EXP(LNTVCL+ETA(1)) ; individual value of CL
V = EXP(LNTVV+ETA(2))
DOSE=1
IPRED=LOG(DOSE/V*EXP(-TIME*CL/V))
Y=IPRED+EPS(1)
$THETA (-0.3667) ; 1. LNTVCL ; (lower bound,initial estimate)
$THETA (0.01) ; 2.LNTVV; (lower bound,initial estimate)
$OMEGA BLOCK(2) 0.0225 ; var ETA(1) ; initial estimate
0.00675 0.0225 ; initial estimate cavariance ETA(1) & ETA(2), var ETA(2)
$SIGMA 0.01 ; var error ; initial estimate
$ESTIMATION METHOD=1 INTER MAXEVAL=9999
;$COVARIANCE
$TABLE ID TIME IPRED CWRES CWRESI NOPRINT ONEHEADER
FILE=sdtab1
$TABLE ID ETA(1) ETA(2) COV1 COV2 NOPRINT NOAPPEND ONEHEADER
FILE=patab1
######################## Final model for AALasso########################################
;;1. Description: Final model for Adjusted Adaptive Lasso. Set up 3, scenario 6,correlation 0.3 among CL & V, ;; correlation of 0.2 among covariates in the data set
;;2. Structural model: one compartment i.v bolus model
;;3 Inter-individual variability: omega is 15%
;;4. Inter-occasion variability: no
;;5. Residual variability: sigma is 10%
$PROBLEM ADDITIVE ERROR MODEL
$INPUT ID TIME AMT EVID DV COV1 COV2 COV3 COV4 COV5 COV6 COV7
COV8 COV9 COV10
$DATA ../../../sserun/m1/mc-sim-4.dat IGNORE=@
; One-compartment model with CL and V
$PRED
CLCOV1 = THETA(3)*(COV1-0.10866)
CLCOV10 = THETA(5)*(COV10+0.17335)
CLCOV2 = THETA(7)*(COV2+0.14651)
CLCOV3 = THETA(9)*(COV3+0.26932)
CLCOV4 = THETA(11)*(COV4+0.49338)
CLCOV5 = THETA(13)*(COV5+0.19860)
CLCOV6 = THETA(15)*(COV6-0.08873)
CLCOV7 = THETA(17)*(COV7+0.17227)
CLCOV8 = THETA(19)*(COV8+0.11337)
CLCOV9 = THETA(21)*(COV9+0.17922)
CLCOV = (CLCOV1)+(CLCOV10)+(CLCOV2)+(CLCOV3)+(CLCOV4)+(CLCOV5)+(CLCOV6)
CLCOV = CLCOV+(CLCOV7)+(CLCOV8)+(CLCOV9)
LNTVCL = THETA(1)
LNTVCL = LNTVCL+CLCOV
LNTVV = THETA(2)
CL = EXP(LNTVCL+ETA(1)) ; individual value of CL
V = EXP(LNTVV+ETA(2))
DOSE=1
IPRED=LOG(DOSE/V*EXP(-TIME*CL/V))
Y=IPRED+EPS(1)
$THETA -0.380364 ; 1. LNTVCL; (lower bound,initial estimate)
$THETA -0.0119521 ; 2.LNTVV; (lower bound,initial estimate)
$THETA 0.27216747536824 FIX ; TH3 CLCOV1
$THETA 1 FIX ; TH4 AL_CLCOV1
$THETA 0 FIX ; TH5 CLCOV10
$THETA 1 FIX ; TH6 AL_CLCOV10
$THETA 0.110905250181566 FIX ; TH7 CLCOV2
$THETA 1 FIX ; TH8 AL_CLCOV2
$THETA 0 FIX ; TH9 CLCOV3
$THETA 1 FIX ; TH10 AL_CLCOV3
$THETA 0 FIX ; TH11 CLCOV4
$THETA 1 FIX ; TH12 AL_CLCOV4
$THETA 0 FIX ; TH13 CLCOV5
$THETA 1 FIX ; TH14 AL_CLCOV5
$THETA 0 FIX ; TH15 CLCOV6
$THETA 1 FIX ; TH16 AL_CLCOV6
$THETA 0 FIX ; TH17 CLCOV7
$THETA 1 FIX ; TH18 AL_CLCOV7
$THETA 0 FIX ; TH19 CLCOV8
$THETA 1 FIX ; TH20 AL_CLCOV8
$THETA 0 FIX ; TH21 CLCOV9
$THETA 1 FIX ; TH22 AL_CLCOV9
$THETA (-1000000,0.05) FIX ; TH23 T-VALUE
$OMEGA BLOCK(2)
0.0354486 ;var ETA(1) ; initial estimate
0.0113629 0.019659 ; initial estimate cavariance ETA(1) & ETA(2), var ETA(2)
$SIGMA 0.0100862 ; var prop err ; initial estimate
$ESTIMATION METHOD=1 INTER MAXEVAL=9999
;$COVARIANCE
MSFO=psn_msf NOABORT
1